ミニロト17年目。一週たりとも予想を休んでいない shirono-j🤠です。

このページでは第二段階の『分析ファイル』を作成。第一段階【①データベース】の続きとなる回だ。

主に「桁」ごとの発生形態と、「No」ごとの発生率分布を分析。ファイル名は『10.桁・発生率』とした。

DT10シートを作る

まずは、このファイル内用のデータテーブルシートを作成する。この後作成する分析用シート達のためのデータベースとなる。

シート名を「DT10」とし、表題(セルA1)には【桁別データテーブル】と見出しを付けた。

テーブルの準備

まずは『00.DB6』ファイルから「DBシート」をコピーする。これを改造するのが早くて楽だ。

コピーしたら、シート名と表題(セルA1)を書き換え、「I～V列」をいったん削除してから、テーブルを「O列」まで広げる。

これが『10.桁・発生率』ファイルの土台となる。

■ データの移植

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

ここでは主に、テータテーブルのデータを『00.DB6』へ同期させる作業となる。

① 現在の回別を示すセルを同期

[A2]へ数式を入力。

=[00.DB6.xlsx]DB!$A$2

② 回別の行を同期

[A4]へ数式を入力。

=[00.DB6.xlsx]DB!A4

③ 抽選日の行を同期

[B4]へ数式を入力。

=IF([00.DB6.xlsx]DB!B4<>"",[00.DB6.xlsx]DB!B4,"")

④ １桁目の行を同期

[C4]へ数式を入力。

=IF([00.DB6.xlsx]DB!C4<>"",[00.DB6.xlsx]DB!C4,"")

② ２桁目の行を同期

[D4]へ数式を入力。

=IF([00.DB6.xlsx]DB!D4<>"",[00.DB6.xlsx]DB!D4,"")

② ３桁目の行を同期

[E4]へ数式を入力。

=IF([00.DB6.xlsx]DB!E4<>"",[00.DB6.xlsx]DB!E4,"")

② ４桁目の行を同期

[F4]へ数式を入力。

=IF([00.DB6.xlsx]DB!F4<>"",[00.DB6.xlsx]DB!F4,"")

② ５桁目の行を同期

[G4]へ数式を入力。

=IF([00.DB6.xlsx]DB!G4<>"",[00.DB6.xlsx]DB!G4,"")

② ６桁目の行を同期

[H4]へ数式を入力。

=IF([00.DB6.xlsx]DB!H4<>"",[00.DB6.xlsx]DB!H4,"")

■ 表頭（ヘッダー）を整える

表頭（ヘッダー）のセル [I3] から [O3] へ以下のヘッダー名を入力する。ここの書式は自分の好みで「折り返して全体を表示する」へ統一した。

• [I3]＝範囲内
• [J3]＝１桁目（%）
• [K3]＝２桁目（%）
• [L3]＝３桁目（%）
• [M3]＝４桁目（%）
• [N3]＝５桁目（%）
• [O3]＝６桁目（%）

分析作業

ここから分析作業に入る。

「各桁」ごとで異なる発生Noの偏りを範囲として割り出し、また、「各No」ごとの発生率を回別毎に算出、分布を調べて統計を取る。

「各桁」と、「各No」のデータを使って、クロスチェック表的なイメージで傾向をつかむ作業だ。

■「過去発生率」をプロットする

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

ここで「過去発生率」と呼ぶのは、各回別時点から見れば「リアルタイム」の発生率履歴である。

言葉で言うより、これから行う計算の数式を見れば一目瞭然だろう。十分に母集団としてのデータ量を確保したいので、「回別＝1000以降」で統計を取る。

① １桁目にでた数字の発生率を算出

[J1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@１桁目])*100/($A1002))

② ２桁目にでた数字の発生率を算出

[K1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@２桁目])*100/($A1002))

③ ３桁目にでた数字の発生率を算出

[L1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@３桁目])*100/($A1002))

④ ４桁目にでた数字の発生率を算出

[M1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@４桁目])*100/($A1002))

⑤ ５桁目にでた数字の発生率を算出

[N1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@５桁目])*100/($A1002))

⑥ ６桁目にでた数字の発生率を算出

[O1003]へ数式を入力。

=IF($B1003="","",COUNTIF($C$4:$H1002,[@６桁目])*100/($A1002))

⑦ セル範囲 [J4]～[O1002] の数式を消去する

上記①～⑥の過程で、EXCELのスピル機能により「1003行より上」にも数式が自動入力されたはずだ。

自分は これを消去して「1003行以降」のデータ、つまり「回別＝1000以降」のデータだけにしておく考えだ。

あと、

書式設定の表示形式で、小数点以下のケタを揃えておく。見やすくするのが目的だ。自分の場合は小数第三位までにした。ここまで済ませた時点で、各列を好みの列幅へ整えるのが良いだろう。

回別に範囲内であったかを判定する

ここから先は、R桁シート完成後の作業。いったん次の「R桁シートを作る」へ進み、あとでまた戻ってくることになる。

DT10シート上で、全ての桁が「設定された下上限」の間にあるかを「回別ごと」に判定し、範囲内は「◎」と表示させる。

■ 各桁数字の範囲判定

DT10シートの、[I4]へ数式を入力。

入力したら「全体分析」に戻る。

=IF(AND(AND(C4>=R桁!$C$3,C4<=R桁!$C$4),AND(D4>=R桁!$D$3,D4<=R桁!$D$4),AND(E4>=R桁!$E$3,E4<=R桁!$E$4),AND(F4>=R桁!$F$3,F4<=R桁!$F$4),AND(G4>=R桁!$G$3,G4<=R桁!$G$4),AND(H4>=R桁!$H$3,H4<=R桁!$H$4))=TRUE,"◎","")

スポンサーリンク

R桁シートを作る

桁別に発生する数字は、ある程度限定されてくる。

その発生範囲（RANGE）を予測するためのツールを作成する。ミニロト予想で培った機能だ。（「桁」ごとの１等出現パターン）

統計で勉強した「Ｚスコア」を使って、最新データに合わせた「最適な範囲設定」を自動算出するように調整するのだ。

シート名を「R桁」とし、表題(セルA1)には【各桁数字の範囲分析】と見出しを付けた。

テーブル枠を作る

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

先にテーブル枠を作成する。

ここでのテーブルは、EXCEL機能のテーブルは挿入しない。数式を含めた構想は先に検討してあるので後ほど入力する。

■ 見出しを準備する

① 範囲設定の算出枠

• [B2]へ「範囲設定」と入力
• [B3]へ「下」と入力
• [B4]へ「上」と入力
• [B5]へ「範囲幅」と入力
• [B6]へ「該当数」と入力
• [B7]へ「該当率」と入力

② 個別分析の算出枠

• [J2]へ「個別分析」と入力
• [J3]へ「平均値」と入力
• [J4]へ「中央値」と入力
• [J5]へ「標準偏差」と入力
• [J6]へ「Ｚスコア上限」と入力
• [J7]へ「Ｚスコア下限」と入力

③ 全体分析の算出枠

• [R2]へ「全体分析」と入力
• 　[S2]へ「発生回数」と入力
• 　[T2]へ「発生率(%)」と入力（注；動画はミスってる）
• [R3]へ「平均」と入力
• [R4]へ「最大」と入力
• [R5]へ「最小」と入力
• [R6]へ「すべての「桁」が 範囲設定内＝◎」と入力
• [R7]へ「どこかの「桁」が 範囲設定外」と入力

④ データ算出枠

• [B8]へ「No」と入力
• [C8]へ「1桁目」と入力
• [D8]へ「2桁目」と入力
• [E8]へ「3桁目」と入力
• [F8]へ「4桁目」と入力
• [G8]へ「5桁目」と入力
• [H8]へ「6桁目」と入力
• [I8]へ「発生回数」と入力（注；動画はミスってる）
• [J8]へ「発生率(%)」と入力
• [K8]へ「1桁目」と入力
• [L8]へ「2桁目」と入力
• [M8]へ「3桁目」と入力
• [N8]へ「4桁目」と入力
• [O8]へ「5桁目」と入力
• [P8]へ「6桁目」と入力

⑤ No枠

[B9]から[B51]へ、Noの「1」から「43」を入力する。

■ 枠を整える

見出しの色や、罫線を整える。動画はあくまで参考。自分の好みに染め上げるのが楽しい。次で数式を入力したあとでは、条件付き書式も投入する。

ここで、

【すべての「桁」が 範囲設定内＝◎】というのが、「各桁数字の大きさ」が相応なパターンの発生率のことで、

【どこかの「桁」が 範囲設定外】というのが、「各桁数字の大きさ」が片寄るパターンの発生率のことである。

数式を入れる

分析データを配置するための数式を入力していく。

『00.DB6』から生データを拾う仕組みなので、DBシートさえきちんと更新していれば 分析値はいつも新鮮だ。

■「No ⇆ 桁」の発生回数

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

基本的には、各桁ごとにNo1から43までの枠を押さえた上で数式を入力し、「Ctrl」と一緒に「Enter」を押す。

① 1桁目をカウント

[C9]へ数式を入力。

=COUNTIF(テーブル1[１桁目],$B9)

② 2桁目をカウント

[D9]へ数式を入力。

=COUNTIF(テーブル1[２桁目],$B9)

③ 3桁目をカウント

[E9]へ数式を入力。

=COUNTIF(テーブル1[３桁目],$B9)

④ 4桁目をカウント

[F9]へ数式を入力。

=COUNTIF(テーブル1[４桁目],$B9)

⑤ 5桁目をカウント

[G9]へ数式を入力。

=COUNTIF(テーブル1[５桁目],$B9)

⑥ 6桁目をカウント

[H9]へ数式を入力。

=COUNTIF(テーブル1[６桁目],$B9)

⑦ ゼロを見えないようにする

これは作る人の自由であるが、セルの書式設定で「表示形式」を調整。ゼロを見えなくして見た目をスッキリさせる。

「ユーザー定義」を使って、以下の種類に設定した。

##0;-#,##0;""

⑧「計」を算出

[I9]へ数式を入力。

=SUM(C9:H9)

⑨「発生率(%)」を算出

[J9]へ数式を入力。書式は小数点第三位までにしておくのが良いと思う。

=I9*100/'DT10'!$A$2

■「No ⇆ 桁」の個別分析

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

Ｚスコアを計算するためのパラメータだ。

Ｚスコアに関してはコチラをチェック→Ｚスコア（Ｚ値）

① 1桁目の平均、中央、標準偏差を算出

[K3]へ数式を入力。

=AVERAGE(テーブル1[１桁目])

[K4]へ数式を入力。

=MEDIAN(テーブル1[１桁目])

[K5]へ数式を入力。

=STDEV.P(テーブル1[１桁目])

② 2桁目の平均、中央、標準偏差を算出

[L3]へ数式を入力。

=AVERAGE(テーブル1[２桁目])

[L4]へ数式を入力。

=MEDIAN(テーブル1[２桁目])

[L5]へ数式を入力。

=STDEV.P(テーブル1[２桁目])

③ 3桁目の平均、中央、標準偏差を算出

[M3]へ数式を入力。

=AVERAGE(テーブル1[３桁目])

[M4]へ数式を入力。

=MEDIAN(テーブル1[３桁目])

[M5]へ数式を入力。

=STDEV.P(テーブル1[３桁目])

④ 4桁目の平均、中央、標準偏差を算出

[N3]へ数式を入力。

=AVERAGE(テーブル1[４桁目])

[N4]へ数式を入力。

=MEDIAN(テーブル1[４桁目])

[N5]へ数式を入力。

=STDEV.P(テーブル1[４桁目])

⑤ 5桁目の平均、中央、標準偏差を算出

[O3]へ数式を入力。

=AVERAGE(テーブル1[５桁目])

[O4]へ数式を入力。

=MEDIAN(テーブル1[５桁目])

[O5]へ数式を入力。

=STDEV.P(テーブル1[５桁目])

⑥ 6桁目の平均、中央、標準偏差を算出

[P3]へ数式を入力。

=AVERAGE(テーブル1[６桁目])

[P4]へ数式を入力。

=MEDIAN(テーブル1[６桁目])

[P5]へ数式を入力。

=STDEV.P(テーブル1[６桁目])

⑦ 書式の表示形式を整える

以下が良いと思う。

• 「平均値」は、小数第一位
• 「中央値」は、標準
• 「標準偏差」は、小数第二位

■「No ⇆ 桁」のＺスコア

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

ここもでも、必要な枠を押さえての「Ctrl＋Enter」で対応する。フィルタリングで隠れているセルには影響を及ぼさないところが大好きだ。（テーブル機能上でだけかもしれんが）

Ｚスコアに関してはコチラをチェック→Ｚスコア（Ｚ値）

① 1桁目のＺスコアを算出

[K9]へ数式を入力。

=(($B9-K$3)/K$5)

② 2桁目のＺスコアを算出

[L9]へ数式を入力。

=(($B9-L$3)/L$5)

③ 3桁目のＺスコアを算出

[M9]へ数式を入力。

=(($B9-M$3)/M$5)

④ 4桁目のＺスコアを算出

[N9]へ数式を入力。

=(($B9-N$3)/N$5)

⑤ 5桁目のＺスコアを算出

[O9]へ数式を入力。

=(($B9-O$3)/O$5)

⑥ 6桁目のＺスコアを算出

[P9]へ数式を入力。

=(($B9-P$3)/P$5)

⑦ Ｚスコアの上限値と下限値を設定する

[K7]へ数式を入力。

=K9

[P6]へ数式を入力。

=P51

⑧ 書式の表示形式を整える

「Zスコア」は、小数第二位までが良いと思う。文字色は薄い灰色。あとで範囲内の数値だけが強調されるように条件付き書式で調整する。

■ 各桁数字の範囲設定

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

Ｚスコアに準じて各桁ごとに「上限と下限」を設定する。回が進み、変動する実績に応じて分析値も自動更新されるように作った。（つもり）

Ｚスコアに関してはコチラをチェック→Ｚスコア（Ｚ値）

① 1桁目の下限を設定

[C3]へ数式を入力。

=43-COUNTIFS(K$9:K$51,">="&$K$7)+1

② 1桁目の上限を設定

[C4]へ数式を入力。

=COUNTIFS(K$9:K$51,"<="&$P$6)

③ 1桁目の範囲幅を設定

[C5]へ数式を入力。

=C4-C3+1

④ 1桁目の範囲該当数をカウント

[C6]へ数式を入力。

=COUNTIF(テーブル1[１桁目],">="&C3)-COUNTIF(テーブル1[１桁目],">"&C4)

⑤ 1桁目の範囲該当率を算出

[C7]へ数式を入力。

=C6/'DT10'!$A$2

⑥ １桁目の計算を横へドラッグ

[C3:C7]を選択し、フィルハンドルをドラッグして数式を６桁目まで展開させる。

⑦ 回別に範囲内であったかを判定

「DT10シート」へ戻り、全ての桁が「①下限」と「②上限」の間にあるかを判定する。回別ごとに判定し、範囲内は「◎」と表示させる。

■ 全体分析

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

① 各数字「発生回数」の 平均、最大、最小を確認

[S3]へ数式を入力。

=AVERAGE(I9:I51)

[S4]へ数式を入力。

=MAX(I9:I51)

[S5]へ数式を入力。

=MIN(I9:I51)

② 各数字「発生率(%)」の 平均、最大、最小を確認

[T3]へ数式を入力。

=AVERAGE(J9:J51)

[T4]へ数式を入力。

=MAX(J9:J51)

[T5]へ数式を入力。

=MIN(J9:J51)

③ 範囲内の「◎」をカウントする

[S6]へ数式を入力。

=COUNTIF(テーブル1[範囲内],"◎")

④ 範囲外の回数を逆算する

[S7]へ数式を入力。

='DT10'!A2-S6

⑤ 範囲内「◎」の発生率を算出する

[T6]へ数式を入力。

=S6*100/'DT10'!A2

⑥ 範囲外の発生率を算出する

[T7]へ数式を入力。

=S7*100/'DT10'!A2

idシートを作る

当せんNoの中で、「どの発生率のNoが」「どのように出現するか」を予想するための分析ツールを準備した。

回別ごとにプロットされた「過去発生率」を分析し、支配的な構成を割り出して予想を組むための一要素として利用する。

シート名を「id」（Incidence Distributionの略）とし、表題(セルA1)には【発生率の分布】と見出しを付けた。

テーブル枠を作る

先にテーブル枠を作成する。

ここでのテーブルは、EXCEL機能のテーブルは挿入しない。数式を含めた構想は先に検討してあるので後ほど入力する。

■ 見出しを準備する

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

① 最新データの表示枠

• [B3]へ「最新データ（現状）」と入力
• [B4]へ「No」と入力
• [C4]へ「発生率(%)」と入力
• [B5]へ「1」と入力
• [B5]から[B47]へ連続データでドラッグ

② 発生率の度数カウント枠

• [E2]へ「～回別＝1000以降での統計～」と入力
• [E3]へ「min」と入力
• [E4]へ「発生率の区間」と入力（注；動画はミスってる）
• [I4]へ「度数」と入力
• [F5]から[F61]へ「以上」と入力
• [H5]から[H61]へ「未満」と入力
• [E62]へ「計」と入力
• [E63]へ「max」と入力

③ 発生率の度数分布分析枠

• [K4]へ「発生率の階級」と入力（注；動画はミスってる）
• [N4]へ「度数」と入力
• [O4]へ「対象No」と入力
• [L5]から[L10]へ「～」と入力

■ 枠を整える

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

自分好みの罫線やフォント、塗りつぶしの色で仕上げて見やすく整える。

発生率の範囲(%)ごとに行った色分けは、このあと分析結果で決めたもの。かなり考えて振り分けた結果だ。

振り分けの根拠はミニロトチャレンジで培った「経験と勘」である。

ちなみに、この動画で使用した色は下表。あとで条件付き書式を設定するときに使用する。

数式を入れて分析する

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

テーブルが三つあるので、左から一つづつ仕上げていく。

発生率の区間を設定して度数を数え、さらに階級分けして度数を合わせる。そのあと、ヒストグラムも作ってみようか。

■ 最新データ（現状）テーブルの算出

R桁シートの[J9]から[J51]をコピーして、

idシートの[C5]から[C47]へリンク貼り付けする。

これで、各数字の最新発生率を この idシート上でも確認できる。いちいち R桁シートへ戻るのは面倒だ。

■ 回別＝1000以降での統計テーブルの算出

① min値の表示

[G3]へ数式を入力。

=MIN(テーブル1[[１桁目（%）]:[６桁目（%）]])

② max値の表示

[G63]へ数式を入力。

=MAX(テーブル1[[１桁目（%）]:[６桁目（%）]])

③ 発生率の範囲の最低値を設定する

[E5]へ数式を入力。

=ROUNDDOWN(G3,1)-0.2

④ 区間の上限をセットする

[G5]へ数式を入力し、[G61]まで書式なしコピー(フィル)する。

=E5+0.1

⑤ 区間の下限をセットする

[E6]へ数式を入力、[E61]まで書式なしコピー(フィル)する。

=G5

⑥ 区間の度数をカウント

[I5]へ数式を入力、[I61]まで書式なしコピー(フィル)する。

=COUNTIFS(テーブル1[[１桁目（%）]:[６桁目（%）]],">="&E5,テーブル1[[１桁目（%）]:[６桁目（%）]],"<"&G5)

⑦ 合計を算出

[I62]へ数式を入力。

=SUM(I5:I61)

■ 発生率の階級を分析する

① 階級下限の設定

[K5]へ数式を入力。

=E5

[K6]へ数式を入力。

=E19

[K7]へ数式を入力。

=E25

[K8]へ数式を入力。

=E31

[K9]へ数式を入力。

=E37

[K10]へ数式を入力。

=E43

② 階級上限の設定

[M5]へ数式を入力。

=G18

[M6]へ数式を入力。

=G24

[M7]へ数式を入力。

=G30

[M8]へ数式を入力。

=G36

[M9]へ数式を入力。

=G42

[M10]へ数式を入力。

=G61

③ 度数の算出

[N5]へ数式を入力、[N10]まで書式なしコピー(フィル)する。

=SUMIFS($I$5:$I$61,$E$5:$E$61,">="&K5,$G$5:$G$61,"<="&M5)

④ 対象となるNoがいくつあるかを数える

[O5]へ数式を入力、[O10]まで書式なしコピー(フィル)する。

=COUNTIFS($C$5:$C$47,">="&K5,$C$5:$C$47,"<"&M5)

⑤ 合計の算出

[N11]へ数式を入力、[O11]まで書式なしコピー(フィル)する。

=SUM(N5:N10)

⑥ ヒストグラムを作成

ヒストグラムを描いて、発生率の分布を見える化する。

※
最後に書式を自分好みに整えた。

条件付き書式で整える

条件付き書式で「見た目」を整える。

分析された情報を大雑把にイメージしやすくなり、且つ「パッと見」である程度の情報を探しやすくなるはずだ。

R桁シートの「範囲設定」を見える化

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

「R桁シート」の、各桁ごとに割り出した設定範囲を見やすくする。

■ 発生回数表を見やすく

[C9:H51]を指示して、条件式書式へ数式を設定する。

色は自分好みへセット。（動画では「C0E6F5」）

=AND(C$3<=$B9,C$4>=$B9)

■ Zスコア表を見やすく

[K9:P51]を指示して、条件式書式へ数式を設定する。

色は自分好みへセット。（動画では「C0E6F5」）

=AND(K9>=$K$7,K9<=$P$6)

全シートの「発生率(%)」を色分けする

「発生率(%)」のデータは、全てのシートで使用している。

各数字ごとに計算された発生率が、どの階級にあるかを色分けして見やすい状態にした。

各階級の色は、idシートで決めた階級色と同じにするとわかりやすい。

■「DT10シート」

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

[J4:O2503]を指示して、条件式書式へ数式を設定する。

① 階級 11.3 ～ 12.7

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値より小さい」にして数式を入力する。

色は自分好みへセット。（動画では「66FFFF」）

=id!$M$5

② 階級 12.7 ～ 13.3

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「00FFFF」）

=id!$K$6

=id!$M$6

③ 階級 13.3 ～ 13.9

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0099FF」）

=id!$K$7

=id!$M$7

④ 階級 13.9 ～ 14.5

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0000FF」）

=id!$K$8

=id!$M$8

⑤ 階級 14.5 ～ 15.1

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「000099」）

=id!$K$9

=id!$M$9

⑥ 階級 15.1 ～ 17.0

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値以上」にして数式を入力する。

色は自分好みへセット。（動画では「000066」）

=id!$K$10

⑦ セルが空白の場合を設定しておく

「指定の値を含むセルだけを書式設定」で「空白」のセルのみを書式設定する。

※
「条件を満たす場合は停止」に ✔チェックを入れておく。

「書式が設定されていません」へセットする（何も書式を指定していない状態）

■「R桁シート」

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

[T3:T5,J9:J51]を指示して、条件式書式へ数式を設定する。

① 階級 11.3 ～ 12.7

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値より小さい」にして数式を入力する。

色は自分好みへセット。（動画では「66FFFF」）

=id!$M$5

② 階級 12.7 ～ 13.3

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「00FFFF」）

=id!$K$6

=id!$M$6

③ 階級 13.3 ～ 13.9

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0099FF」）

=id!$K$7

=id!$M$7

④ 階級 13.9 ～ 14.5

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0000FF」）

=id!$K$8

=id!$M$8

⑤ 階級 14.5 ～ 15.1

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「000099」）

=id!$K$9

=id!$M$9

⑥ 階級 15.1 ～ 17.0

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値以上」にして数式を入力する。

色は自分好みへセット。（動画では「000066」）

=id!$K$10

■「idシート」

※文字まで読めるきれいな画像はYouTubeへ移動する必要あり

[C5:C47]を指示して、条件式書式へ数式を設定する。

① 階級 11.3 ～ 12.7

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値より小さい」にして数式を入力する。

色は自分好みへセット。（動画では「66FFFF」）

=$M$5

② 階級 12.7 ～ 13.3

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「00FFFF」）

=$K$6

=$M$6

③ 階級 13.3 ～ 13.9

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0099FF」）

=$K$7

=$M$7

④ 階級 13.9 ～ 14.5

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「0000FF」）

=$K$8

=$M$8

⑤ 階級 14.5 ～ 15.1

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値の間」にして数式を二つ入力。

色は自分好みへセット。（動画では「000099」）

=$K$9

=$M$9

⑥ 階級 15.1 ～ 17.0

▶指定の値を含むセルだけを書式設定 で「セルの値」を「次の値以上」にして数式を入力する。

色は自分好みへセット。（動画では「000066」）

=$K$10

次のステップに進む

【②桁範囲と発生率の分析】編は、いったんここまで。次の【③week】編へと進む。ゴールはまだ遠い。

！作成中！